Posted Jul 18, 2022 19:00 UTC (Mon) by qyliss (guest, #131684) [Link]

Since version 9.1, cat in GNU coreutils will use copy_file_range if possible. Surprisingly, it's actually the first program in coreutils to use that API. Which means that, for a disk image build I have, that requires assembling individual partition images into a combined GPT image, it's significantly faster to write each partition into place with cat than it is to use dd, which I'd have expected to be the better tool for the job.

Posted Jul 19, 2022 10:45 UTC (Tue) by ddevault (subscriber, #99589) [Link]

Here's my implementation of cat in Hare, for general interest. io::copy uses sendfile when possible, and perhaps splice could also be added, but the extra pipe(2) is not great IMO, could fail if file descriptors are exhausted and has other side-effects besides. Simplicity trumps efficiency for tools like this in my book.

use fmt;
use fs;
use getopt;
use io;
use main;
use os;

export fn utilmain() (main::error | void) = {
	const cmd = getopt::parse(os::args,
		('u', "POSIX compatibility, ignored"),
		"[file...]");
	defer getopt::finish(&cmd);

	if (len(cmd.args) == 0) {
		io::copy(os::stdout, os::stdin)?;
		return;
	};

	for (let i = 0z; i < len(cmd.args); i += 1z) {
		const file = open(cmd.args[i]);
		match (io::copy(os::stdout, file)) {
		case size => void;
		case let err: io::error =>
			io::close(file): void;
			return err;
		};
		io::close(file)?;
	};
};

fn open(path: str) io::handle = {
	if (path == "-") {
		return os::stdin;
	};

	match (os::open(path)) {
	case let err: fs::error =>
		fmt::fatal("Error opening '{}': {}", path, fs::strerror(err));
	case let file: io::file =>
		return file;
	};
};

Conill: How efficient can cat(1) be?

Conill: How efficient can cat(1) be?